# ARMv7 banana-pi-r2

buildarch=4

pkgbase=linux-armv7
_srcname=linux
_kernelname=${pkgbase#linux}
_desc="ARMv7 banana-pi-r2"
pkgver=6.4.3
pkgrel=1
#rcnver=5.8.5
#rcnrel=armv7-x11
arch=('armv7h')
url="http://www.kernel.org/"
license=('GPL2')
makedepends=('xmlto' 'docbook-xsl' 'kmod' 'inetutils' 'bc' 'git' 'uboot-tools' 'vboot-utils' 'dtc')
options=('!strip')
source=()
md5sums=()

prepare() {
    cd "${srcdir}/${_srcname}"

    # add upstream patch
    #git apply --whitespace=nowarn ../patch-${pkgver}
    git apply --whitespace=nowarn ${srcdir}/../../kernel/patches/patch-${pkgver}

    # RCN patch
    #git apply ../patch-${rcnver%.0}-${rcnrel}.diff

    # ALARM patches
    #git apply ../0001-ARM-atags-add-support-for-Marvell-s-u-boot.patch
    #git apply ../0002-ARM-atags-fdt-retrieve-MAC-addresses-from-Marvell-bo.patch
    #git apply ../0003-SMILE-Plug-device-tree-file.patch
    #git apply ../0004-fix-mvsdio-eMMC-timing.patch
    #git apply ../0005-net-smsc95xx-Allow-mac-address-to-be-set-as-a-parame.patch
    #git apply ../0006-set-default-cubietruck-led-triggers.patch
    #git apply ../0007-exynos4412-odroid-set-higher-minimum-buck2-regulator.patch
    #git apply ../0008-ARM-dove-enable-ethernet-on-D3Plug.patch
    #git apply ../0009-USB-Armory-MkII-support.patch

    cat "${srcdir}/../../kernel/config-${pkgver}" > ./.config

    # add pkgrel to extraversion
    #sed -ri "s|^(EXTRAVERSION =)(.*)|\1 \2-${pkgrel}|" Makefile

    # don't run depmod on 'make install'. We'll do this ourselves in packaging
    sed -i '2iexit 0' scripts/depmod.sh
}

build() {
    cd "${srcdir}/${_srcname}"

    # get kernel version
    make prepare

    # load configuration
    # Configure the kernel. Replace the line below with one of your choice.
    #make menuconfig # CLI menu for configuration
    #make nconfig # new CLI menu for configuration
    #make xconfig # X-based configuration
    #make oldconfig # using old config from previous kernel version
    # ... or manually edit .config

    # Copy back our configuration (use with new kernel version)
    #cp ./.config ../${pkgbase}.config

    ####################
    # stop here
    # this is useful to configure the kernel
    #msg "Stopping build"
    #return 1
    ####################

    #yes "" | make config

    # build!
    make ${MAKEFLAGS} -j4 zImage modules dtbs
}

_package() {
    pkgdesc="The Linux Kernel and modules - ${_desc}"
    depends=('coreutils' 'linux-firmware' 'kmod' 'mkinitcpio>=0.7')
    optdepends=('crda: to set the correct wireless channels of your country')
    backup=("etc/mkinitcpio.d/${pkgbase}.preset")
    provides=("linux=${pkgver}" "WIREGUARD-MODULE")
    conflicts=('linux')
    replaces=('linux-mvebu' 'linux-udoo' 'linux-sun4i' 'linux-sun5i' 'linux-sun7i' 'linux-usbarmory' 'linux-wandboard' 'linux-clearfog')
    install=${pkgname}.install

    cd "${srcdir}/${_srcname}"

    KARCH=arm

    # get kernel version
    _kernver="$(make kernelrelease)"
    _basekernel=${_kernver%%-*}
    _basekernel=${_basekernel%.*}

    mkdir -p "${pkgdir}"/{boot,usr/lib/modules}
    make INSTALL_MOD_PATH="${pkgdir}/usr" modules_install
    make INSTALL_DTBS_PATH="${pkgdir}/boot/dtbs" dtbs_install
    cp arch/$KARCH/boot/zImage "${pkgdir}/boot/zImage"

    # make room for external modules
    local _extramodules="extramodules-${_basekernel}${_kernelname}"
    ln -s "../${_extramodules}" "${pkgdir}/usr/lib/modules/${_kernver}/extramodules"

    # add real version for building modules and running depmod from hook
    echo "${_kernver}" |
	install -Dm644 /dev/stdin "${pkgdir}/usr/lib/modules/${_extramodules}/version"

    # remove build and source links
    rm "${pkgdir}"/usr/lib/modules/${_kernver}/{source,build}

    # now we call depmod...
    depmod -b "${pkgdir}/usr" -F System.map "${_kernver}"

    # sed expression for following substitutions
      local _subst="
    s|%PKGBASE%|${pkgbase}|g
    s|%KERNVER%|${_kernver}|g
    s|%EXTRAMODULES%|${_extramodules}|g
  "

      # install mkinitcpio preset file
      sed "${_subst}" ../linux.preset |
	  install -Dm644 /dev/stdin "${pkgdir}/etc/mkinitcpio.d/${pkgbase}.preset"

      # install pacman hooks
      sed "${_subst}" ../60-linux.hook |
	  install -Dm644 /dev/stdin "${pkgdir}/usr/share/libalpm/hooks/60-${pkgbase}.hook"
      sed "${_subst}" ../90-linux.hook |
	  install -Dm644 /dev/stdin "${pkgdir}/usr/share/libalpm/hooks/90-${pkgbase}.hook"
}

_package-headers() {
    pkgdesc="Header files and scripts for building modules for linux kernel - ${_desc}"
    provides=("linux-headers=${pkgver}")
    conflicts=('linux-headers')
    replaces=('linux-mvebu-headers' 'linux-sun4i-headers' 'linux-sun5i-headers' 'linux-sun7i-headers' 'linux-usbarmory-headers' 'linux-wandboard-headers' 'linux-clearfog-headers')

    cd ${_srcname}
    local _builddir="${pkgdir}/usr/lib/modules/${_kernver}/build"

    install -Dt "${_builddir}" -m644 Makefile .config Module.symvers
    install -Dt "${_builddir}/kernel" -m644 kernel/Makefile

    mkdir "${_builddir}/.tmp_versions"

    cp -t "${_builddir}" -a include scripts

    install -Dt "${_builddir}/arch/${KARCH}" -m644 arch/${KARCH}/Makefile
    install -Dt "${_builddir}/arch/${KARCH}/kernel" -m644 arch/${KARCH}/kernel/asm-offsets.s 

    cp -t "${_builddir}/arch/${KARCH}" -a arch/${KARCH}/include
    #for i in dove exynos omap2; do
#	mkdir -p "${_builddir}/arch/${KARCH}/mach-${i}"
#	cp -t "${_builddir}/arch/${KARCH}/mach-${i}" -a arch/$KARCH/mach-${i}/include
 #   done
 #   for i in omap orion samsung versatile; do
#	mkdir -p "${_builddir}/arch/${KARCH}/plat-${i}"
#	cp -t "${_builddir}/arch/${KARCH}/plat-${i}" -a arch/$KARCH/plat-${i}/include
 #   done

    install -Dt "${_builddir}/drivers/md" -m644 drivers/md/*.h
    install -Dt "${_builddir}/net/mac80211" -m644 net/mac80211/*.h

    # http://bugs.archlinux.org/task/13146
    install -Dt "${_builddir}/drivers/media/i2c" -m644 drivers/media/i2c/msp3400-driver.h

    # http://bugs.archlinux.org/task/20402
    install -Dt "${_builddir}/drivers/media/usb/dvb-usb" -m644 drivers/media/usb/dvb-usb/*.h
    install -Dt "${_builddir}/drivers/media/dvb-frontends" -m644 drivers/media/dvb-frontends/*.h
    install -Dt "${_builddir}/drivers/media/tuners" -m644 drivers/media/tuners/*.h

    # add xfs and shmem for aufs building
    mkdir -p "${_builddir}"/{fs/xfs,mm}

    # copy in Kconfig files
    find . -name Kconfig\* -exec install -Dm644 {} "${_builddir}/{}" \;

    # remove unneeded architectures
    local _arch
    for _arch in "${_builddir}"/arch/*/; do
	[[ ${_arch} == */${KARCH}/ ]] && continue
	rm -r "${_arch}"
    done

    # remove files already in linux-docs package
    rm -r "${_builddir}/Documentation"

    # remove now broken symlinks
    find -L "${_builddir}" -type l -printf 'Removing %P\n' -delete

    # Fix permissions
    chmod -R u=rwX,go=rX "${_builddir}"

    # strip scripts directory
    local _binary _strip
    while read -rd '' _binary; do
	case "$(file -bi "${_binary}")" in
	    *application/x-sharedlib*)  _strip="${STRIP_SHARED}"   ;; # Libraries (.so)
	    *application/x-archive*)    _strip="${STRIP_STATIC}"   ;; # Libraries (.a)
	    *application/x-executable*) _strip="${STRIP_BINARIES}" ;; # Binaries
	    *) continue ;;
	esac
	/usr/bin/strip ${_strip} "${_binary}"
    done < <(find "${_builddir}/scripts" -type f -perm -u+w -print0 2>/dev/null)
}

#pkgname=("${pkgbase}" "${pkgbase}-headers" "${pkgbase}-smileplug" "${pkgbase}-mirabox" "${pkgbase}-ax3" "${pkgbase}-d3plug" "${pkgbase}-cubox" "${pkgbase}-chromebook" "${pkgbase}-odroidc1")
pkgname=("${pkgbase}" "${pkgbase}-headers")
for _p in ${pkgname[@]}; do
      eval "package_${_p}() {
    _package${_p#${pkgbase}}
  }"
done