import org.jetbrains.compose.compose
import org.jetbrains.compose.desktop.application.dsl.TargetFormat
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
    kotlin("jvm") version "1.5.21"
    kotlin("plugin.serialization") version "1.5.21"
    id("org.jetbrains.compose") version "1.0.0-alpha3"
}

group = "de.pheerai"
version = "1.0.0-SNAPSHOT"

repositories {
    mavenCentral()
    google()
    maven("https://maven.pkg.jetbrains.space/public/p/compose/dev")
}

dependencies {
    implementation(compose.desktop.currentOs)
    implementation("org.jetbrains.kotlinx", "kotlinx-serialization-json", "1.2.2")
    implementation("com.github.ajalt.clikt", "clikt-jvm", "3.2.0")
    implementation("com.github.ajalt.clikt", "clikt", "3.2.0")
    testImplementation(kotlin("test", "1.5.21"))
}

tasks.test {
    useJUnitPlatform()
}

tasks.withType<KotlinCompile> {
    kotlinOptions.jvmTarget = JavaVersion.VERSION_16.toString()
    kotlinOptions.freeCompilerArgs += "-Xopt-in=kotlin.RequiresOptIn"
}

compose.desktop {
    application {
        mainClass = "MainKt"
        nativeDistributions {
            targetFormats(TargetFormat.Pkg)
            packageName = "jeopardy"
            val fullVersion = (project.version as String)
            packageVersion = if (fullVersion.contains("-SNAPSHOT")) {
                fullVersion.removeSuffix("-SNAPSHOT")
            } else {
                fullVersion
            }
        }
    }
}