buildscript {
    extra.apply {
        set("coroutinesVersion", "1.4.1")
        set("jsoupVersion", "1.13.1")
        set("kotestVersion", "4.3.1")
        set("kotlinxHtmlVersion", "0.7.2")
        set("cliktVersion", "3.0.1")
        set("kotlinVersion", "1.4.20-RC")
    }
}

plugins {
    `java-platform`
    `maven-publish`
}

group = "de.pheerai"
version = "0.0.2-SNAPSHOT"

repositories {
    jcenter()
    mavenCentral()
    mavenLocal {
        mavenContent {
            includeGroup("de.pheerai.eap")
            includeGroup("de.pheerai")
        }
    }
}

javaPlatform {
    allowDependencies()
}

dependencies {
    api(platform("org.jetbrains.kotlin:kotlin-bom:${getFromExtra<String>("kotlinVersion")}"))
    api(platform("org.jetbrains.kotlinx:kotlinx-coroutines-bom:${getFromExtra<String>("coroutinesVersion")}"))

    api("org.jetbrains.kotlinx", "kotlinx-coroutines-core")

    api("com.github.ajalt.clikt", "clikt", getFromExtra("cliktVersion"))
    api("org.jsoup", "jsoup", getFromExtra("jsoupVersion"))

    api("org.jetbrains.kotlinx", "kotlinx-html-jvm", getFromExtra("kotlinxHtmlVersion"))

    api("io.kotest", "kotest-runner-junit5-jvm", getFromExtra("kotestVersion"))
    api("io.kotest", "kotest-assertions-core-jvm", getFromExtra("kotestVersion"))
}

publishing {
    publications {
        create<MavenPublication>("NativeBom") {
            from(components["javaPlatform"])
        }
    }
}

inline fun <reified T> getFromProperties(name: String): T = project.properties[name] as T
inline fun <reified T> getFromExtra(name: String): T = extra[name] as T