import org.jetbrains.kotlin.gradle.plugin.mpp.KotlinNativeTarget

plugins {
    id("org.jetbrains.kotlin.multiplatform")
}
repositories {
    mavenCentral()
}
group = "com.example"
version = "0.0.1"

apply(plugin = "maven-publish")

kotlin {
    jvm()
    js {
        // FIXME: JS-Tests
        browser {
            testTask {
                enabled = false
            }
        }
        nodejs {
            testTask {
                enabled = false
            }
        }
    }
    // For ARM, should be changed to iosArm32 or iosArm64
    // For Linux, should be changed to e.g. linuxX64
    // For MacOS, should be changed to e.g. macosX64
    // For Windows, should be changed to e.g. mingwX64

    linuxX64("linuxX64")
    linuxArm64("linuxArm64")
    linuxArm32Hfp("linuxArm32")
    targets.withType<KotlinNativeTarget> {
        binaries {
            executable {
                entryPoint("de.pheerai.rcdbquery.main")
            }
        }
    }

    sourceSets {
        commonMain {
            dependencies {
                implementation(kotlin("stdlib-common"))
            }
        }
        commonTest {
            dependencies {
                implementation(kotlin("test-common"))
                implementation(kotlin("test-annotations-common"))
            }
        }
        getByName("jvmMain") {
            dependencies {
                implementation(kotlin("stdlib-jdk8"))
            }
        }
        getByName("jvmTest") {
            dependencies {
                implementation(kotlin("test"))
                implementation(kotlin("test-junit"))
            }
        }
        getByName("jsMain") {
        }
        getByName("jsTest") {
            dependencies {
                implementation(kotlin("test-js"))
            }
        }
        getByName("linuxX64Main") {
        }
        getByName("linuxX64Test") {
        }
        getByName("linuxArm64Main") {
        }
        getByName("linuxArm64Test") {
        }
        all {
            languageSettings.enableLanguageFeature("InlineClasses")
        }
    }
}