day6: solve part 1 & 2

day6/part1/main.d

@@ -0,0 +1,37 @@
+import std.algorithm;
+import std.uni;
+import std.array;
+import std.file;
+import std.stdio;
+
+void main()
+{
+    readText("input").calculateTotalNumberOfQuestions.writeln;
+}
+
+auto calculateTotalNumberOfQuestions(string input)
+{
+    return input.splitter("\n\n")
+        .array.map!(group => group.filter!isAlpha.array.sort.uniq.count).sum;
+}
+
+unittest
+{
+    auto input = `abc
+
+a
+b
+c
+
+ab
+ac
+
+a
+a
+a
+a
+
+b`;
+
+    assert(input.calculateTotalNumberOfQuestions == 11);
+}

day6/part2/main.d

@@ -0,0 +1,51 @@
+import std.algorithm;
+import std.uni;
+import std.array;
+import std.file;
+import std.stdio;
+import std.range;
+import std.conv;
+import std.string;
+
+void main()
+{
+    readText("input").calculateTotalNumberOfQuestions.writeln;
+}
+
+auto setIntersectionRoR(RoR)(RoR ror)
+{
+    assert(!ror.empty);
+    return ror.map!(to!(dchar[]))
+        .reduce!((r1, r2) => r1.setIntersection(r2).array);
+}
+
+auto calculateTotalNumberOfQuestions(string input)
+{
+    return input.splitter("\n\n").array.map!((group) {
+        return group.splitter.map!(person => person.representation.dup.sort.array.assumeUTF)
+            .setIntersectionRoR.count;
+    }).sum;
+}
+
+unittest
+{
+    auto input = `abc
+
+a
+b
+c
+
+ab
+ac
+
+a
+a
+a
+a
+
+b
+
+yx`;
+
+    assert(input.calculateTotalNumberOfQuestions == 8);
+}